Chapter 3, Part 2: The Large-Z Approximation and Symmetry Adapted Sturmian Bases

The Large-Z Approximation

When nuclear attraction dominates completely over interelectron repulsion, the term (Subscript[T, ν'ν]^′) can be neglected in Eq. (3.39), such that we obtain

(Subscript[E, κ])->-(1/2)(Z^2)((Subscript[ℛ, ν])^2)==-(1/2)(Z^2)((1/(Subscript[n, 1]^2))+⋯+(1/(Subscript[n, N]^2)))

In other words, the energy levels of an N-electron atom become those of N independent electrons moving in the attractive potential of a nucleus with charge Z. We introduce the name “ℛ-block” for the set of primitive configurations that are degenerate when repulsion is neglected, and we write (Subscript[T, (Subscript[R, ν])]^′) for the (finite dimensional) block of T' corresponding to the span of this set.

Even when Z is large, interelectron repulsion hybridizes the set of degenerate primitive configurations belonging to a particular value of (Subscript[ℛ, ν]) and slightly removes the degeneracy. The large-Z approximation consists in neglecting all configurations outside the ℛ-block and solving Eq. (3.39) one block at a time.

For each block, the restricted nuclear attraction matrix is a multiple of the unit matrix and so does not affect eigenvectors. Thus if {(Subscript[λ, κ])} are the eigenvalues of (Subscript[T, (Subscript[ℛ, ν])]^′), i.e. are solutions to

(Subscript[T, (Subscript[ℛ, ν])]^′)(Subscript[Ψ, κ])==(Subscript[λ, κ])(Subscript[Ψ, κ])

then the solutions to

((Subscript[Zℛ, ν])I+(Subscript[T, (Subscript[ℛ, ν])]^′))(Subscript[Ψ, κ])==(Subscript[(OverBar[p]), κ])(Subscript[Ψ, κ])

are (Subscript[(OverBar[p]), κ])==(Subscript[Zℛ, ν])+(Subscript[λ, κ]) such that

(Subscript[(OverBar[E]), κ])==-((Subscript[(OverBar[p]), κ]^2)/2)==-(1/2)((((Subscript[Zℛ, ν])+(Subscript[λ, κ])))^2)

The bars over (Subscript[(OverBar[E]), κ]) and (Subscript[(OverBar[p]), κ]) serve to remind us of the very restricted basis. This gives us an extraordinarily simple way of crudely approximating bound states of atoms. (Subscript[T, (Subscript[ℛ, ν])]^′)-blocks may be diagonalized once and for all, each root characterizing with a single number a state throughout the entire isoelectronic series.

Example: The Carbonlike (Subscript[ℛ, ν])==(Sqrt[3])-block

Initialization  We begin by loading the libraries that we will use:

Get["Sturmian`"];
Get["Sturmian`binary`"];
Get["Sturmian`M`pauli`"];
Get["Sturmian`M`identify`"];

For the six electron isoelectronic series, the ℛ-block that dominates the ground state is given by

(Subscript[ℛ, ν])==(Sqrt[(2/(1^2))+(4/(2^2))])==(Sqrt[3])

One can see in this expression that the block consists of all six-electron configurations of which two are in the n==1 shell and four are in the n==2 shell. For each of the configurations there are four valence electrons with n==2 and a full n==1 shell. We therefore build the basis by constructing the set of all n==2 four-electron configurations that obey the Pauli principle, and then combining all of them with the filled n==1 shell:

o2=oneelectronstates[2,2];
core={{1,0,0,-1},{1,0,0,1}};
basis=Join[core,#]&/@binomialchoices[o2,4];

The number of configurations in the block is thus given by the binomial coefficient (({{8}, {4}}))=70, since this is the number of ways to choose four different one-electron states from the eight that have n==2.

Length[basis]

Having now constructed the configurations in the (Subscript[ℛ, ν])==(Sqrt[3]) block, we compute (Subscript[T, (Sqrt[3])]^′), the corresponding block of the energy independent interelectron repulsion matrix, and calculate the roots. The roots of T' are all negative, and in equation ( ), they reduce the effect of nuclear attraction, as is understandable since they represent interelectron repulsion. Thus a root with a small absolute value corresponds to a tightly bound state; we reverse the list of eigenvalues so that they appear in order from most to least tightly bound.

Trep=repulsionMatrix[basis];

roots=Reverse[Eigenvalues[Trep]];
λ=Reverse[Union[Round[roots,N[10^(-7)]]]];
multiplicities=Length/@Split[Round[roots,10^(-7)]];

The degeneracies of these roots are given by (2L+1)·(2S+1) where L and S are respectively the total orbital momentum and total spin quantum numbers. The roots and degeneracies of the ℛ-block are as follows:

λ
multiplicities

Identification of the Eigenstates

The nondegenerate roots correspond unambiguously to (^1)S-states, but in general the identification of the states requires a further step. For example, a root of degeneracy 5 may either correspond to a state of symmetry (^1)D or (^5)S. To identify the symmetries to which the roots correspond, we must examine the eigenvectors. We would like the eigenvectors to have the have the familiar Russell-Saunders form. These are defined to be simultaneous eigenvectors of the operators (L^2), (Subscript[L, Z]), (S^2) and (Subscript[S, Z]). For the Russell-Saunders states, the (2L+1)·(2S+1)-fold degeneracy corresponds to the ranges

(Subscript[M, L])∈{-L,-L+1,…,L-1,L},   (Subscript[M, S])∈{-S,-S+1,…,S-1,S}

of their eigenvalues of (Subscript[L, Z]) and (Subscript[S, Z]). It can be seen from this that the largest value of (Subscript[M, L]) and the largest value of (Subscript[M, S]) give us the quantum numbers for total angular momentum (L^2) and total spin (S^2) (corresponding to the operators’ eigenvalues L(L+1) and S(S+1)).

Simply diagonalizing the (Subscript[T, (Sqrt[3])]^′)-block will result in eigenfunctions that are some linear combinations of Russell-Saunders states. They will be eigenfunctions of (L^2) and (S^2), but not necessarily of (Subscript[L, Z]) and (Subscript[S, Z]). To ensure that we will obtain Russell-Saunders states, we will remove the degeneracy slightly by adding to (Subscript[T, (Sqrt[3])]^′) an extremely small perturbation

(Subscript[ϵ, 1])(Subscript[L, z])+(Subscript[ϵ, 2])(Subscript[S, Z])

where (Subscript[ϵ, 1]) and (Subscript[ϵ, 2]) are chosen such that the perturbations do not interfere with each other. When we diagonalize the perturbed block of T', we obtain Russell-Saunders states. These can then be examined to determine unambiguously the symmetries of the degenerate states. In the following, the function perturb solves the very slightly perturbed eigensystem discussed above.

printedbasis=MatrixForm[{MatrixForm/@#}]&/@basis;
{λP,cP}=Reverse/@perturb[Trep,basis,10^(-8)];

We obtain the index of the first eigenfunction in each multiplet :

firstindex=Table[1+Sum[multiplicities[[i]],{i,j}],{j,0,Length[λ]-1}]

The first 9 degenerate Russell-Saunders states dominate the ground state of the Carbonlike isoelectronic series. These are shown below:

Chop[#].printedbasis&/@Take[cP,9]//MatrixForm

Examining the states in the multiplet, we can notice that the maximal value of (Subscript[M, L])==(∑_(i==1)^6)(Subscript[m, i]) is 1 and the maximal value of 2(Subscript[M, S])==(∑_(i==1)^6)(Subscript[2(Subscript[m, s]), i]) is 2; thus the multiplet corresponds to a (^3)P.

The coefficients in the linear combinations of configurations forming the Russell-Saunders states could have been derived with great effort from group theory. Here they appear automatically. In our example, we are working with Goscinskian configurations, but had the radial functions been derived from for example Hartree-Fock theory, the coefficients would have been the same, since they depend only on angular momentum and spin.

We’ll define a function that pretty-prints the eigenfunctions in a multiplet for us:

showmultiplet[κ_]:=
MatrixForm[Chop[Take[cP,{firstindex[[κ]],firstindex[[κ+1]]-1}],10^(-7)].printedbasis]

Next comes the 5-fold degenerate multiplet, which we determine to be a (^1)D multiplet:

showmultiplet[2]

Then comes a (^1)S:

showmultiplet[3]

The reader is urged to examine other eigenvectors and other isoelectronic series.

The process of generating Russell-Saunders states given an ℛ-block and classifying the symmetries of the multiplets has been automated by the function classify:

classify[Trep,basis,10^(-8)]

The symmetries are given as pairs (L,S). This can also be shown in spectroscopic notation by applying the function term2label as is shown below:

{#[[1]],term2label[#[[2]]]}&/@classify[Trep,basis,10^(-8)]

Comparison of the large-Z approximation to experiment

We now turn to a quantitative comparison of this crude but rapid approximation to the spectroscopically obtained energies for the Carbonlike isoelectronic series. In the following graph, the large-Z approximation

(Subscript[(OverBar[E]), κ])==-(1/2)((((Subscript[Zℛ, ν])+(Subscript[λ, κ])))^2)

is plotted against energies from the NIST Atomic Spectra Database. We also plot (Subscript[(OverBar[E]), κ])/(Z^2) (the rightmost graph) to better see the fine structure.

Get["Sturmian`data`groundstates`"];(*Load NIST-data*)

Enonrel=-1/2 (Z*Sqrt[3]+λ)^2;

Show[
Plot[Evaluate@Table[Enonrel[[κ]],{κ,12}],{Z,6,40}],
ListPlot[Cgroundstates],
PlotRange->All
]

Show[
Plot[Evaluate@Table[Enonrel[[κ]]/Z^2,{κ,12}],{Z,6,40}],
ListPlot[CgrounddivZZ],
PlotRange->{{0,40},{-1,-1.5}},AxesOrigin->{0,-1.5}
]

As we noted also in the previous notebook, the approximation tends towards the exact non-relativistic solution as the nuclear charge Z increases; but at the same time, as Z grows, the non-relativistic Schrödinger equation less and less accurately describes nature’s atoms and ions. To estimate relativistic effects we once again use the rough correction of multiplying the non-relativistic energies by the ratio

(Subscript[f, κ])(Z)==((Subscript[E, rel])/(Subscript[E, nonrel]))==(((∑_ν)(Subscript[B, νκ]^2)⟨(Subscript[Φ, ν])|(Subscript[H, 0])|(Subscript[Φ, ν])⟩_rel)/((∑_ν)(Subscript[B, νκ]^2)⟨(Subscript[Φ, ν])|(Subscript[H, 0])|(Subscript[Φ, ν])⟩_nonrel))==(((∑_ν)(Subscript[B, νκ]^2)⟨(Subscript[Φ, ν])|(Subscript[H, 0])|(Subscript[Φ, ν])⟩_rel)/(-(1/2)(Z^2)(∑_ν)(Subscript[B, νκ]^2)((Subscript[ℛ, ν])^2)))

where (Subscript[H, 0]) is a sum of one-electron Hamiltonian operators corresponding to single electrons moving in the field of the bare nucleus, i.e. interelectron repulsion is completely neglected. We have exact closed-form solutions for this problem (using Equations (7.35)-(7.40)), that are made available by the following package:

Get["Sturmian`Relativistic`oneelectron`"];

Rν=mkR[basis];
ben=basisenergies[basis,Z];
correction=correctionfactors[cP[[#]]&/@firstindex,ben,Rν,Z];

We can inspect the expression for one of these correction factors (in this case the correction for the ground state multiplet):

correction[[1]]

By looking at the numerical values as Z increases, we can see that the factor is close to one when the nuclear charge is small but becomes increasingly appreciable as Z grows:

correction[[1]]/.Z->Range[6,40]

The following two graphs show the crudely corrected energies (Subscript[f, κ])(Subscript[(OverBar[E]), κ]) as well as (((Subscript[f, κ])(Subscript[(OverBar[E]), κ]))/(Z^2)).

Erel=-1/2*correction*(Z*Sqrt[3]+λ)^2;

Show[
Plot[Evaluate@Table[Erel[[κ]],{κ,12}],{Z,6,50}],
ListPlot[Cgroundstates],
PlotRange->All,AxesOrigin->{0,-1.5}
]
Show[
Plot[Evaluate@Table[Erel[[κ]]/Z^2,{κ,12}],{Z,6,50}],
ListPlot[CgrounddivZZ],
PlotRange->{{0,40},{-1,-1.5}},AxesOrigin->{0,-1.5}
]

We note that the large-Z approximation, despite it’s great simplicity, well approximates non-relativistic energies; even for modest values of nuclear charge, the error of the large-Z approximation is smaller than the error due to neglecting relativity. Further, relativistic effects may be accounted for with the cost of some overhead, obtaining energies that correspond well to experiment.

The example presented here (the ground state of the carbonlike isoelectronic series) is a case not easily approximated using a small number of Goscinskian basis functions, because interelectron repulsion plays a large role. Nevertheless, it can be seen that even in this difficult case, the large-Z approximation gives very reasonable results. The large-Z approximation is not only extremely simple, but it is characterized by a small number of parameters - the roots of the interelectron repulsion matrix. These roots are dimensionless and independent of energy and of nuclear charge. They can be calculated once and for all, and they contain information concerning many states of the entire isoelectronic series. Once the roots are obtained, calculating approximate atomic energies becomes a task that can be performed on the back of an envelope.

The reader is urged to try the method for other values of the principle quantum numbers (Subscript[n, 1]),…,(Subscript[n, N]) and for other isoelectronic series.