Calculations used in Chapter 3 : Goscinskian Basis Sets

The N-particle non-relativistic Schrödinger equation can be written on the form

(-(Δ/2)+V(x)-(Subscript[E, κ]))(Subscript[Ψ, κ])(x)==0, where Δ==(∑_(j==1)^N)(1/(Subscript[m, j]))(Subscript[∇, j]^2)

In the generalized Sturmian method, we build up solutions from linear combinations of isoenergetic solutions to an approximate Schrödinger equation with a weighted potential:

(-(Δ/2)+(Subscript[β, ν])(Subscript[V, 0])(x)-(Subscript[E, κ]))(Subscript[Φ, ν])(x)==0

The weighting factors (Subscript[β, ν]) are especially chosen in such a way that every solution (Subscript[Φ, ν]) corresponds to the same energy (Subscript[E, κ]), and this energy is set equal to that of the state being represented. For the case of atoms or atomic ions, this seemingly difficult problem can be solved exactly when (Subscript[V, 0]) is taken to be the Coulomb attraction of the bare nucleus. The solutions are Slater determinants

(Subscript[Φ, ν])==|(Subscript[χ, (Subscript[μ, 1])])…(Subscript[χ, (Subscript[μ, N])])|

where the (Subscript[χ, μ]), μ==(n,l,m,(Subscript[m, s])), are hydrogenlike spin-orbitals with a weighted nuclear charge (Subscript[Q, ν]). As it is shown in Chapter 3, the weighted nuclear charge needed for this purpose is

(Subscript[Q, ν])==((Subscript[p, κ])/(Subscript[ℛ, ν])),where(Subscript[p, κ])==(Sqrt[-2(Subscript[E, κ])])(Subscript[andℛ, ν])==((((∑_(j==1)^N)(1/(Subscript[n, j]^2))))^(1/2))

(This type of generalized Sturmian configuration we call "Goscinskian configurations" to honour the pioneering work of Osvaldo Goscinski.) We are led (Eqs. 3.30-3.39) to a set of generalized Sturmian secular equations of the form

(Zℛ+T')(Subscript[Ψ, κ])==(Subscript[p, κ])(Subscript[Ψ, κ]),where(Subscript[Ψ, κ])==(∑_ν)(Subscript[Φ, ν])(Subscript[B, νκ])

The nuclear attraction matrix is Zℛ and is diagonal. Written in a way that makes the diagonality of the nuclear attraction matrix more apparent, the secular equations are:

(∑_ν)((Subscript[Zℛ, ν])(Subscript[δ, (νν)'])+(Subscript[T, (νν)']^′)-(Subscript[p, κ])(Subscript[δ, (νν)']))(Subscript[B, νκ])==0

Here T' is the energy-independent interelectron repulsion matrix defined by Eq. 3.32:

(Subscript[T, ν'ν]^′)==-(1/(Subscript[p, κ]))⟨(Subscript[Φ, ν'])|V'(x)|(Subscript[Φ, ν])⟩,whereV'(x)==(∑_(1≤i<j≤N))(1/(Subscript[r, ij]))

For a given number of electrons N, the energy-independent interelectron repulsion matrix T' can be calculated once and for all, and used for many states and any value of Z.

As an example of this method, we will calculate a large of number of excited states of the two-electron isoelectronic series. In its present form, the method is most suitable for rapidly computing large numbers of excited states of few-electron systems, as is discussed in the preface of our book. A more realistic choice of (Subscript[V, 0]) than the nuclear attraction potential used with Goscinskian configurations would extend the range of N for which convergence is rapid.

Initialization

We begin by loading the libraries that we will need:

Get["Sturmian`"]
Get["Sturmian`binary`"]
Get["Sturmian`M`pauli`"]

We next generate or load a basis. For example, we here generate an appropriate basis for calculating triplet S-states of the two-electron isoelectronic series (showing the generated basis):

basis3S = Flatten[Table[{{n, 0, 0, 1}, {np, 0, 0, 1}}, {n, 1, 10}, {np, n + 1, 10}], 1]

A basis of N-electron configurations should be given in the form of a list of N-tuples of one-electron quantum numbers (n,l,m,2(Subscript[m, s])). Thus the 2-electron basis above lists pairs of one-electron quantum numbers. For example, the first basis-configuration is represented by {{1,0,0,1},{2,0,0,1}}, corresponding to the 1s2s (^3)S configuration

Φ(x)==(1/(Sqrt[2!]))|({{ (Subscript[χ, 100(1/2)])((Subscript[x, 1])) ,  (Subscript[χ, 200(1/2)])((Subscript[x, 1])) }, { (Subscript[χ, 100(1/2)])((Subscript[x, 2])) ,  (Subscript[χ, 200(1/2)])((Subscript[x, 2])) }})|

Computing the Atomic Spectrum

The next two operations respectively calculate the interelectron repulsion matrix T' and the (Subscript[ℛ, ν])’s that are needed for the nuclear attraction term.

Trep3S = repulsionMatrix[basis3S]; 
 R3S = mkR[basis3S];  
 T3S = Z*DiagonalMatrix[R3S] + Trep3S;

We are now in a position to compute a spectrum of (^3)S excited states for the entire two-electron isoelectronic series. The eigenvalues obtained are values of the scaling parameter (Subscript[p, κ]), related to the energies by (Subscript[p, κ])==(Sqrt[-2(Subscript[E, κ])]). We build a table of eigenvalues corresponding to the first seven (^3)S excited states for He, Li(SuperPlus[]), Be(^(2+)),…,Zn(^(28+)).

Zmax = 40;
  p3S = Table[Eigenvalues[T3S, 7], {Z, 2, Zmax}]; 
  energies3S = -p3S*p3S/2;

The table below shows the energies of the states; The first column corresponds to He, the second to Li(SuperPlus[]), and so on. The dominant configurations of the excited states are 1s2s, 1s3s,…, 1s7s.

TableForm[Transpose[energies3S]]

The graph below shows the binding energies (Subscript[E, κ]) plotted as functions of Z. The lines denote the calculated values; the dots are experimental values from the NIST Atomic Spectra Database.

Get["Sturmian`data`hedata`"]; (* Load the NIST-numbers *)
 plot1 = Show[
   ListPlot[Table[{Z, energies3S[[Z - 1, κ]]}, {κ, 1, 7}, {Z, 2, Zmax}], Joined -> True],
   ListPlot[Helike3S],

   ImageSize->500
 ]

More details can be seen if (Subscript[E, κ])/(Z^2) is plotted as a function of Z, as shown below.

plot2 = Show[

   ListPlot[Table[{Z, energies3S[[Z - 1, κ]]/Z^2}, {κ, 1, 7}, {Z, 2, Zmax}], Joined -> True],
   ListPlot[{#[[1]], #[[2]]/#[[1]]^2} & /@ Helike3S],

   ImageSize->500
  ]

For low values of nuclear charge Z, the agreement between calculated and experimental result is excellent. As Z increases, the Goscinskian solutions approach the exact solution to the non-relativistic Schrödinger equation. However, relativistic effects begin to be important at around Z==10, and therefore the calculated values begin to differ as relativity becomes more and more important.

Correcting for Relativistic Effects

In order to make a rough correction, we can construct the ratio between the relativistic and non-relativistic energies of a configuration, assuming interelectron repulsion to be completely neglected, so that the energy is equal to that of N independent electrons moving in the field of the nucleus.

In the nonrelativistic case, the energy of a hydrogenlike spin-orbital is given by -((Z^2)/(2(n^2))), and thus the total energy of an N-electron configuration is -(1/2)(Z^2)((Subscript[ℛ, ν])^2).

In the relativistic case, the energy of a single electron in a hydrogenlike orbital is given in Chapter 7, Equations (7.35) through (7.40). The expression in (7.40) includes the rest energy, which must be subtracted when we make a comparison with the non-relativistic energy.

We wish to compare the two energies (Subscript[E, rel]) and (Subscript[E, nonrel]) for a multiconfigurational state

(Subscript[Ψ, κ])==(∑_ν)(Subscript[Φ, ν])(Subscript[B, νκ])

the ratio being

(Subscript[f, κ])(Z)==((Subscript[E, rel])/(Subscript[E, nonrel]))==(((∑_ν)(Subscript[B, νκ]^2)⟨(Subscript[Φ, ν])|(Subscript[H, 0])|(Subscript[Φ, ν])⟩_rel)/((∑_ν)(Subscript[B, νκ]^2)⟨(Subscript[Φ, ν])|(Subscript[H, 0])|(Subscript[Φ, ν])⟩_nonrel))==(((∑_ν)(Subscript[B, νκ]^2)⟨(Subscript[Φ, ν])|(Subscript[H, 0])|(Subscript[Φ, ν])⟩_rel)/(-(1/2)(Z^2)(∑_ν)(Subscript[B, νκ]^2)((Subscript[ℛ, ν])^2)))

Here, (Subscript[H, 0]) is a sum of one-electron Hamiltonian operators corresponding to single electrons moving in the field of the bare nucleus, i.e. interelectron repulsion is completely neglected.

The package Relativistic`onelectron` provides functions to compute the relativistic one-electron energies, the independent-electron energy for a multiconfigurational state as well as the correction ratios (Subscript[f, κ])(Z).

Get["Sturmian`Relativistic`oneelectron`"];
 ?Sturmian`Relativistic`oneelectron`*

We first compute the relativistic energies ⟨(Subscript[Φ, ν])|(Subscript[H, 0])|(Subscript[Φ, ν])⟩_rel for each configuration (Subscript[Φ, ν]) in our basis.

basisErel = basisenergies[basis3S, Z];

We then obtain the eigenfunctions of T and proceed to compute the relativistic to non-relativistic ratio (Subscript[f, κ])(Z)

cs = #[[2]] & /@ Table[Eigensystem[T3S], {Z, 2, Zmax}];
 fκ = Table[correctionfactors[cs[[Z - 1]], basisErel, R3S, Z], {Z, 2, Zmax}];

The next figure compares the corrected energies to experiment:

plot3 = Show[
    ListPlot[Table[{Z, fκ[[Z - 1, κ]]*energies3S[[Z - 1, κ]]/Z^2}, 
                   {κ, 1, 7}, {Z, 2, Zmax}], Joined -> True],
    ListPlot[{#[[1]], #[[2]]/#[[1]]^2} & /@ Helike3S],

    ImageSize->500
  ]

The rough relativistic correction is seen to bring the calculated energies into close agreement with the experimental ones for all values of nuclear charge Z. Thus the generalized Sturmian method using Goscinskian configurations is seen to be an extremely useful tool for the analysis of the spectra of atoms and atomic ions, provided that a relativistic correction is made.

We will now look more closely at the deviations between calculated and experimental energies. The following line of code pairs calculated energies to the closest experimental values from NIST:

match = Table[Nearest[Helike3S, {Z, fκ[[Z - 1, κ]]*energies3S[[Z - 1, κ]]}, 1][[1, 2]], 
                {Z, 2, 30}, {κ, 3}];

Our final step is to generate and plot two tables: one showing the relative error with respect to experiment of the calculated energies without the relativistic correction, and the other the relative error when the correction is included.

nonreldiffs = Table[{Z, -(energies3S[[Z-1, κ]]-match[[Z-1, κ]])/match[[Z-1, κ]]}, 
                      {κ, 3}, {Z, 2, 30}];

  reldiffs = Table[{Z,-(fκ[[Z-1,κ]]*energies3S[[Z-1,κ]]-match[[Z-1,κ]])/match[[Z-1,κ]]}, 
                      {κ, 3}, {Z, 2, 30}];

        
  Show[
       ListPlot[nonreldiffs],
       ListPlot[reldiffs],
       
       AxesOrigin->{0,0},PlotRange->All,

       ImageSize->500
   ]

The general appearence of this graph is strikingly similar to Figure 7.2 in our book, which plots exact solutions to the one-electron hydrogenlike Schrödinger equation and its relativistic counterpart, the Dirac equation. This builds confidence that for high values of Z, the deviations are less due to inaccuracies in either the Sturmian method, incompleteness of the basis set or the roughness of the relativistic correction. Rather it seems that for of the relativistically corrected values, the deviations are due to quantum electrodynamic effects.